home *** CD-ROM | disk | FTP | other *** search
/ MacWorld 1999 January - Disc 2 / Macworld (1999-01) (Disk 2).dmg / Mac OS 8.5 Updaters / RealPC⁄Soft Windows / RealPC / RealPC Upgrade Disk / INSIGNIA / WIN310UP.BAT < prev    next >
Encoding:
DOS Batch File  |  1998-08-24  |  2.4 KB  |  90 lines
  1. @echo off
  2. rem [
  3. rem    Name:        u.win310up.bat
  4. rem
  5. rem    Derived from:    u.w31batch.bat and u.swupdate.bat
  6. rem
  7. rem    Author:        Bruce Godden
  8. rem
  9. rem    Created on:    August 1997
  10. rem
  11. rem    Sccs ID:    @(#)u.win310up.bat    1.1 08/28/97
  12. rem
  13. rem    Coding Stds:    
  14. rem
  15. rem    Purpose:    Batch file for manual update of a US Windows 3.1
  16. rem            disk. Assumes that the normal 3.11 update has
  17. rem            already been run (if it matters).
  18. rem
  19. rem    Parameters:    1    Windows system directory
  20. rem                (Default is c:\windows\system)
  21. rem
  22. rem    Copyright 1997 Insignia Solutions PLC. All rights reserved.
  23. rem ]
  24.  
  25. rem  Ensure we have 'our' directory.
  26. if not exist c:\insignia\nul md c:\insignia
  27.  
  28. rem  Append this log file to the existing log file.
  29. echo %0 %1 %2 %3 %4 %5 %6 %7 %8 %9    >>c:\insignia\up.log
  30. echo. | date                >>c:\insignia\up.log
  31. echo. | time                >>c:\insignia\up.log
  32. vol c:                    >>c:\insignia\up.log
  33. rem  Append to the history file.
  34. echo %0 %1 %2 %3 %4 %5 %6 %7 %8 %9    >>c:\insignia\uphist.log
  35. echo. | date                >>c:\insignia\uphist.log
  36. echo. | time                >>c:\insignia\uphist.log
  37. vol c:                    >>c:\insignia\uphist.log
  38.  
  39. set SysDir=%1
  40. if "%1" == "" set SysDir=c:\windows\system
  41. if not exist %SysDir%\user.exe goto End
  42.  
  43. set WinVer=win310
  44.  
  45. echo Updating your configuration. Please wait...
  46.  
  47. c:
  48. cd \insignia
  49.  
  50. rem We need to work out which VTD to patch. (I think it will always
  51. rem be the one in the WIN386 file, but it doesn't hurt to check.)
  52.  
  53. find /v ";" c:\windows\system.ini | find /i "device=vtda.386" >nul:
  54. if not errorlevel 1 goto VTDASection
  55.  
  56. find /v ";" c:\windows\system.ini | find /i "device=vtd.386" >nul:
  57. if not errorlevel 1 goto VTDSection
  58.  
  59. rem The following sections patch the components we are interested in.
  60. rem Some of these may already have been patched by the win311 update.
  61. rem It doesn't hurt to try them again ... and we might patch them to
  62. rem a proper win310 version anyway!
  63.  
  64. rem Patch the VTD in the WIN386 file
  65. call patchone win386.exe %SysDir% -VTD -%WinVer%
  66. goto PatchTheRest
  67.  
  68. :VTDASection
  69. rem Patch the VTDA file
  70. call patchone vtda.386 %SysDir% -VTD -%WinVer%
  71. goto PatchTheRest
  72.  
  73. :VTDSection
  74. rem Patch the VTD file
  75. call patchone vtd.386 %SysDir% -VTD -%WinVer%
  76.  
  77. :PatchTheRest
  78.  
  79. call patchone gdi.exe %SysDir% -GDI -%WinVer%
  80.  
  81. rem No patch available for krnl386.exe unfortunately.
  82.  
  83. call patchone v7vdd.386 %SysDir% -V7VDD -%WinVer%
  84.  
  85. call patchone win386.exe %SysDir% -WIN386 -LOADER -%WinVer%
  86.  
  87. call patchone win386.exe %SysDir% -WIN386 -VMM -%WinVer%
  88.  
  89. :End
  90.